home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / antdesgn.arc / LPDA.BAS < prev    next >
Encoding:
BASIC Source File  |  1980-01-01  |  1.5 KB  |  59 lines
  1. 10 REM LOG PERIODIC DIPOLE ARRAY PROGRAM
  2. 20 REM "ANTENNA DESIGN USING PERSONAL COMPUTERS"
  3. 30 DATA .139,.782,.147,.822,.157,.865,.163,.892,.168,.916,.172,.928
  4. 40 DATA .174,.940,.176,.950,.178,.964
  5. 50 DIM SIG(9),TAU(9)
  6. 60 REM FILL ARRAYS
  7. 70 FOR I=1 TO 9
  8. 80 READ SIG(I),TAU(I)
  9. 90 NEXT I
  10. 100 PI=3.141593
  11. 110 KEY OFF
  12. 120 CLS
  13. 130 COLOR 1,0
  14. 140 PRINT "LOG-PERIODIC ARRAY DESIGN"
  15. 150 COLOR 4,0
  16. 160 PRINT
  17. 170 INPUT "WHAT IS THE LOWER FREQUENCY(MHz)";FMIN
  18. 180 INPUT "WHAT IS THE UPPER FREQUENCY(MHz)";FMAX
  19. 190 INPUT "WHAT IS THE DESIRED GAIN(dB)(BETWEEN 8 AND 12)";D0
  20. 200 IF D0<8 OR D0>12 THEN GOTO 190
  21. 210 INPUT "WHAT IS THE RADIUS OF THE LARGEST DIPOLE(meters)";A1
  22. 220 COLOR 14,0
  23. 230 REM INTERPOLATE TO FIND SIGMA, TAU
  24. 240 I1%=2*D0-15
  25. 250 IF I1%<1 THEN I1%=1
  26. 260 IF I1%>9 THEN I1%=9
  27. 270 I2%=I1%+1
  28. 280 IF I2%>9 THEN I2%=9
  29. 290 DI=(I1%+15)/2
  30. 300 S=SIG(I1%)+2*(D0-DI)*(SIG(I2%)-SIG(I1%))
  31. 310 T=TAU(I1%)+2*(D0-DI)*(TAU(I2%)-TAU(I1%))
  32. 320 PRINT
  33. 330 PRINT "SIGMA,TAU=",S,T
  34. 340 ALP=ATN((1-T)/(4*S))
  35. 350 XL=300/FMIN
  36. 360 LOD=.25*XL/A1
  37. 370 F=LOD/(1+LOD)
  38. 380 DO=0
  39. 390 AO=A1
  40. 400 LO=.48*F*XL
  41. 410 XL=300/FMAX
  42. 420 LMIN=.48*XL
  43. 430 I=0
  44. 440 PRINT "DIPOLE #  SPACING  LENGTH   RADIUS"
  45. 450 I=I+1
  46. 460 PRINT USING " ##      ##.####  ##.####   .####";I,DO,LO,AO
  47. 470 IF LO<LMIN THEN GOTO 520
  48. 480 DO=2*S*LO
  49. 490 LO=T*LO
  50. 500 AO=LO*.5/LOD
  51. 510 GOTO 450
  52. 520 PRINT
  53. 530 COLOR 4,0
  54. 540 INPUT "CONTINUE(Y,N)";IS$
  55. 550 IF IS$<>"N" THEN GOTO 120
  56. 560 COLOR 7,0
  57. 570 KEY ON
  58. 580 END
  59.